home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Aminet 30
/
Aminet 30 (1999)(Schatztruhe)[!][Apr 1999].iso
/
Aminet
/
util
/
dtype
/
f1gp_bkg_dt.lha
/
f1gp_bkg_dt
/
Install_F1GP_BKG_Datatype
< prev
next >
Wrap
Text File
|
1999-02-11
|
2KB
|
75 lines
; $VER: Install_F1GP_BKG_DataType 1.3 (25.3.97)
; by Oliver Roberts (oliver.roberts@iname.com)
;
; French translation by Daniel Grenson
(if (= (exists "Env:Language") 1)
(set @language (getenv "Language"))
)
;*****************
; English strings
;
(set #str-kick3 "You must be running Kickstart 3.0 or higher to use datatypes.")
(set #str-cpu "Choose which version of the datatype to install")
(set #str-installdt "Installing Datatype")
(set #str-installclass "Installing f1gp_bkg.datatype class")
(set #str-installdes "Installing Format Descriptors")
;****************
; French strings
;
(if (= @language "français") (
(set #str-kick3 "Vous devez fonctionner avec un Kickstart 3.0 ou supérieur pour utilise des datatypes.")
(set #str-cpu "Choisissez la version de datatype à installer")
(set #str-installdt "Installing Datatype")
(set #str-installclass "Installation de f1gp_bkg.datatype class")
(set #str-installdes "Installation des descripteurs de format")
))
;*************
; Here we go!
;
(set @default-dest "")
(set #cpu (database "cpu"))
(set #cpu020 (and (<> #cpu "68000") (<> #cpu "68010")))
(if (< (/ (getversion) 65536) 39)
(abort #str-kick3)
)
(set #cpu020
(askchoice
(help @askchoice-help)
(prompt #str-cpu)
(choices "68000" "68020+")
(default #cpu020)
)
)
(working #str-installdt)
(if (<> (exists "SYS:Classes") 2) (makedir "SYS:Classes" (infos)) )
(set #dtname "Classes/DataTypes/f1gp_bkg.datatype")
(if #cpu020 (set #dtname (cat #dtname ".020")))
(copylib
(help @copylib-help)
(prompt #str-installclass)
(source #dtname)
(dest "SYS:Classes/DataTypes")
(newname "f1gp_bkg.datatype")
(confirm)
)
(copyfiles
(help @copyfiles-help)
(prompt #str-installdes)
(source "Devs/DataTypes/F1GP Backdrop")
(dest "DEVS:DataTypes")
(infos)
(confirm)
)
(run "C:AddDataTypes >NIL: REFRESH")